Cristhian Vergara

miércoles, 23 de mayo de 2012

Cambiar y Proteger la cadena de conexion del app.config

La cadena de conexión es un dato sensible, por tal razón es necesario protegerla, de aquellos usuarios emprendedores o alguno que te odie. Para ciertas aplicaciones se necesita modificar la cadena de conexión en tiempo de ejecución.

En siguiente formulario permite leer, cambiar en tiempo de ejecución y proteger la cadena de conexión.

Agrego a mi proyecto el archivo app.config:

<?xml version="1.0" encoding="utf-8" ?>
<configuration>
  
  <connectionStrings>
    <add  name="cnxVentasDemo"
          connectionString="Server=(local)\SQL2008;DataBase=VentasDemo;Integrated Security=SSPI;"
          providerName="System.Data.SqlClient" />
  </connectionStrings>
  
</configuration>

Agrego la referencia a System.Configuration y el respectivo Imports:

Imports System.Configuration
  
Public Class Form1
  
  
End Class

El siguiente código permite la lectura de la cadena de conexión:

Private Sub btnObtieneCNX_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnObtieneCNX.Click
        Dim MiCnx As ConnectionStringSettings
  
        MiCnx = ConfigurationManager.ConnectionStrings("CNXVentasDemo")
  
        If Not MiCnx Is Nothing Then
            txtCadenaConexion.Text = MiCnx.ConnectionString
        End If
    End Sub

Para proteger la cadena de conexión, se abrirá el app.config, luego la sección connectionsString y finalmente preguntar si la sección esta protegida o no.

Private Sub btnProtegerCNX_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnProtegerCNX.Click
  
       Try
           'Se abre el app.config para recuperar la seccion ConnectionStrings
           Dim MiAppConfig As Configuration = _
           ConfigurationManager.OpenExeConfiguration(Application.ExecutablePath)
  
           'Se recupera la seccion ConnectionStrings
           Dim MiSeccion As ConnectionStringsSection = _
           DirectCast(MiAppConfig.GetSection("connectionStrings"),  ConnectionStringsSection)
  
           'Se protege la seccion, caso contrario se desprotege
           If MiSeccion.SectionInformation.IsProtected Then
               MiSeccion.SectionInformation.UnprotectSection()
           Else
  
               MiSeccion.SectionInformation.ProtectSection("DataProtectionConfigurationProvider")
           End If
  
           'Se guarda los cambios
           MiAppConfig.Save()
  
           If MiSeccion.SectionInformation.IsProtected Then
               MessageBox.Show("Cadena de Conexion Protegida")
           Else
               MessageBox.Show("No esta protegida")
           End If
  
       Catch ex As Exception
           MessageBox.Show(ex.Message)
       End Try
   End Sub

La aplicación no necesita descifrar la sección connectionString, este paso es realizando automáticamente.

Para cambiar la cadena de conexión en tiempo de ejecución tenemos:

Private Sub btnCambiarCNX_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnCambiarCNX.Click
       'Se abre el app.config para recuperar la seccion ConnectionStrings
       Dim MiAppConfig As Configuration = _
       ConfigurationManager.OpenExeConfiguration(Application.ExecutablePath)
  
       'Se recupera la seccion ConnectionStrings
       Dim MiSeccion As ConnectionStringsSection = _
       DirectCast(MiAppConfig.GetSection("connectionStrings"), ConnectionStringsSection)
  
       'Se establece el nuevo valor de la cadena de conexion
       MiSeccion.ConnectionStrings("CNXVentasDemo").ConnectionString = txtCadenaConexion.Text
  
       'Se guarda los cambios
       MiAppConfig.Save()
  
       MessageBox.Show("Se guardo la cadena de conexion. Cierre la aplicación ó Reinicio la aplicación")
  
       'Se reinicia la aplicación
       Application.Restart()
  
   End Sub

Es necesario reiniciar la aplicación o cerrarla, ya que la carga inicial se encuentra en la cache de la aplicación y por este motivo no se ve el cambio

martes, 22 de mayo de 2012

Para que sirve el patron Singleton?

Etiquetas: ADO.NET, SQL Server 2008, Visual Basic 10, Visual Studio 2008, Visual Studio 2010

Antes de contestar la pregunta “¿Para que sirve el patrón Singleton?”; contestemos esta: ¿Qué es el patrónSingleton? , según Wikipedia:

El patrón de diseño Singleton (instancia única) está diseñado para restringir la creación de objetos pertenecientes a una clase o el valor de un tipo a un único objeto. Su intención consiste en garantizar que una clase sólo tenga una instancia y proporcionar un punto de acceso global a ella. (http://es.wikipedia.org/wiki/Singleton) En el articulo escrito por León Weliki para MSDN, profundiza sobre el tema en cuestión (http://msdn.microsoft.com/es-es/library/bb972272.aspx).

Resumiendo las definiciones, el patrón Singleton me asegura que solo se creará una única instancia de la clase. Contestando a la segunda pregunta, para que me sirve?. Empecemos a definir un contexto donde pueda aplicar este patrón; normalmente las tablas de clientes y proveedores tienen un campo Distrito, que es el lugar donde se encuentra ubica la empresa. Es muy probable que en cada mantenimiento hagamos uso de la instancia de la clase Distrito con la finalidad de obtener los datos, entonces la conexión a la base de datos se hará varias veces cargando los mismos datos, pero en diferentes formularios, aquí podemos centralizar la carga de los datos por única vez, y que luego pueda ser usada en diferentes partes de la aplicación.

Se crea la clase Distrito que implemente el patrón Singleton:

Imports System.Data.SqlClient
  
Public Class Distrito
    Private Shared Instancia As Distrito = Nothing
    Private dt As New DataTable
  
    'Se inicia el constructor por unica vez
    Private Sub New()
        Dim cnx As New SqlConnection("Server=.\SQL2008;Database=VentasDemo;Integrated Security=SSPI;")
        Dim cmd As New SqlCommand("Select Cod_Dis, Nom_Dis From TB_Distrito Order By Nom_Dis", cnx)
  
        cnx.Open()
        dt.Load(cmd.ExecuteReader)
        cnx.Close()
    End Sub
    Public Shared Function getInstancia() As Distrito
        If Instancia Is Nothing Then
            Instancia = New Distrito()
        End If
        Return Instancia
    End Function
    Public Function GetDistritos() As DataTable
        Return dt
    End Function
End Class

El método getInstancia asegura que la clase tenga una única instancia, por lo tanto el constructor se ejecuta una sola vez, es aquí donde colocare el código que carga los distritos de la base de datos, y los almacenare en un objeto DataTable. Observe que por una sola vez se conectara a la base de datos para obtener los datos de distritos, para luego usarlo en toda la aplicación. El objeto Instancia me indicara si se creo la instancia de Distrito, caso contrario es nulo. El método GetDistritos devuelve el objeto DataTable, con los datos cargados.

Para probar la clase Distrito, creare tres formularios: FormMDI, que será mi formulario principal, Form1 que será el mantenimiento de Clientes y el Form2 será el mantenimiento de Proveedores. En cada formulario creare el objeto Distrito, pero solo en uno de ellos se crea la instancia.

Para el FormMDI, tengo el siguiente diseño:

Cristhian Vergara

Páginas

viernes, 1 de junio de 2012